Impersonar con Visual Basic .NET

Existen ocasiones que necesitamos lanzar un proceso con otro usuario porque el usuario que ejecuta la aplicación no tiene privilegios suficientes para acceder a ciertas funcionabilidades una posible solución es la impersonación.

Podemos traducir la impersonción como una personificación del usuario actual a otro usuario para la realización de ciertas tareas. Por ejemplo se puede usar cuando tenemos una aplicación que en cierto punto debe ejecutar un proceso de sistema que las GPO prohiben que se ejecute con el usuario que ha iniciado MS Windows y por lo tanto la aplicación.

Creamos la clase Impersonate será la encargada de recoger los datos del usuario que queremos impersonar y tambien la que realice las acciones pertinentes para imperosnarse.

Imports System.Security.Principal
Imports System.Runtime.InteropServices

Public Class Impersonate

    Const LOGON32_LOGON_INTERACTIVE As Integer = 2
    Const LOGON32_PROVIDER_DEFAULT As Integer = 0

    Dim impersonationContext As WindowsImpersonationContext

    Declare Function LogonUserA Lib "advapi32.dll" (ByVal lpszUsername As String, _
                            ByVal lpszDomain As String, _
                            ByVal lpszPassword As String, _
                            ByVal dwLogonType As Integer, _
                            ByVal dwLogonProvider As Integer, _
                            ByRef phToken As IntPtr) As Integer

    Declare Auto Function DuplicateToken Lib "advapi32.dll" ( _
                            ByVal ExistingTokenHandle As IntPtr, _
                            ByVal ImpersonationLevel As Integer, _
                            ByRef DuplicateTokenHandle As IntPtr) As Integer

    Declare Auto Function RevertToSelf Lib "advapi32.dll" () As Long
    Declare Auto Function CloseHandle Lib "kernel32.dll" (ByVal handle As IntPtr) As Long

    Public Function impersonateValidUser(ByVal userName As String, _
                    ByVal domain As String, ByVal password As String) As Boolean

        Dim tempWindowsIdentity As WindowsIdentity
        Dim token As IntPtr = IntPtr.Zero
        Dim tokenDuplicate As IntPtr = IntPtr.Zero
        impersonateValidUser = False

        If RevertToSelf() Then
            If LogonUserA(userName, domain, password, LOGON32_LOGON_INTERACTIVE, LOGON32_PROVIDER_DEFAULT, token) <> 0 Then
                If DuplicateToken(token, 2, tokenDuplicate) <> 0 Then
                    tempWindowsIdentity = New WindowsIdentity(tokenDuplicate)
                    impersonationContext = tempWindowsIdentity.Impersonate()
                    If Not impersonationContext Is Nothing Then
                        impersonateValidUser = True
                    End If
                End If
            End If
        End If
        If Not tokenDuplicate.Equals(IntPtr.Zero) Then
            CloseHandle(tokenDuplicate)
        End If
        If Not token.Equals(IntPtr.Zero) Then
            CloseHandle(token)
        End If
    End Function

    Public Sub deshacerImpersonacion()
        ' revierte la impersonacion y deja al usaurio anterior
        impersonationContext.Undo()
    End Sub

    Public Function infoUsrActual()
        ' devuelve la informacion del usuario actual
        Return System.Security.Principal.WindowsIdentity.GetCurrent().Name
    End Function

End Class

Ahora desde cualquier clase de nuestro proyecto podemos impersonar simplemente realizando una llamada a Impersonate, de esta forma:

        Dim imp As New Impersonate
        imp.impersonateValidUser("usuarioImpersonado", "dominio", "contraseña")

Y a partir de aquí lo que ejecutemos se realizará con el usuario que hayamos impersonado.

No olvides usar deshacerImpersonacion() de la clase Impersonate para volver al usuario inicial, no deseamos que se impersone para toda la apliación.

Más datos en Microsoft Developer Network